产品
一、问题描述
AC梁和CD梁通过铰接连接，其中长度a =1 m，梁的直径0.02 m，弹性模量E= 200 GPa，泊松比μ = 0.3。在B点受力偶距的作用，在C点受集中力的作用，F = 20N。利用ANSYS计算，练习梁与梁铰接的处理方法，并画剪力图和弯矩图，研究剪力图和弯矩图的正负规定。
图1 梁与梁铰接连接的力学分析
二、问题分析
铰链传力不传力偶矩，与铰相连的两横截面上，弯矩M = 0，剪力FS不一定为零。
用BEAM188梁单元建模。在A点约束UY、UZ、ROTX和ROTY，在D点全约束。
AC梁的A、B和C点的分别建立关键点1、2和3，1和2连线生成L1，2和3连线生成L2，L1和L2共用关键点2，几何体是连续的，划分网格后节点也是连续的；CD梁的C和D点的分别建立关键点分别4和5，4和5连续生成L3。由于L2和L3在C点不共用关键点，导致几何体是不连续的，AC梁和CD梁划分网格后，节点在C位置处会有2个节点，AC梁在C点的节点号为12，CD梁在C点的节点号为22。AC梁和CD梁在C点的节点分别是节点12和22，节点不共用，不能传递载荷。为了在C点能够传递传力而不传递力偶矩，可通过耦合这两个节点的平动自由度实现。
铰链连接两根梁的GUI操作路径：Main Menu>Preprocessor> Coupling / Ceqn> Couple DOFs。见图2，拾取节点12，再拾取节点22 →OK → NSET中输入1，Lab中选择UX；重复操作，再拾取12和22节点，NSET中输入2，Lab中选择UY；再重复操作，再拾取12和22节点，NSET中输入3，Lab中选择UZ。完成分别耦合三个方向的平动自由度的操作。
图2 梁与梁通过耦合自由度实现铰接连接
三、剪力图和弯矩图正负的规定
从图3可见，最大剪力30N，最大弯矩30N.m，与材料力学计算结果完全吻合。在C点是铰接点，弯矩图在此处弯矩为零，实现了梁与梁的铰接连接。
图3 梁的内力图（关键点连线顺序从左到右）
刘鸿文版《材料力学》、孙训方版《材料力学》，还有《结构力学》中都对梁的内力的正负有自己的一套规定。回顾一下刘鸿文版《材料力学》中弯曲内力正负的规定：左段对右段向上相对错动时，规定剪力为正；反之，为负。弯曲变形凸向下时，规定为正；反之，为负。
但是发现力学教材中剪力和弯矩正负的规定与ANSYS中正负的规定是不一样的，那么ANSYS是如何规定剪力和弯矩的正负的呢？例如图3中弯矩图的正负与刘鸿文版《材料力学》中规定一致，剪力图的正负与规定的正负相反，这是为什么呢？
先分析得到图3的建模过程，AC梁：1和2连线生成L1，2和3连线生成L2；CD梁：4和5连续生成L3。生成线1时，关键点的连线顺序是先拾取关键点1，再拾取关键点2；其他生成其他两条线的关键点连线顺序也是从左到右。
如果两个关键点的连线顺序都变成从右到左，在C点出需要耦合的节点变成12和23，将这两个节点耦合平动自由度，经过计算后，得到的剪力图和弯矩图如图4所示，剪力图的正负仍然保持不变，但是弯矩图的正负与图3相反。再细致观察发现，图3的剪力图都是画在+Y一侧，而图4中的剪力图都画在-Y一侧。初步分析发现，剪力图和弯矩图的正负似乎与连线的顺序有关。
图4 梁的内力图（关键点连线顺序从右到左）
在ANSYS分析中，从不同的视图看，哪是左段哪是右段？弯曲变形哪是凸哪是凹？因此是不能确定的。ANSYS的对内力正负的规定估计应该是以坐标系为基础，得到的以上两种内力图的结果在整体坐标系下是没有变的，坐标系可能发生改变的就是单元坐标系了。回顾一下，通过定义单元表，梁单元的内力是在单元坐标系下的结果，因此梁的内力正负规定应该就是与单元坐标系有关。
（1）关闭单元形状：Utility Menu >PlotCtrls >Style >Size and Shape →[/ESHAPE]：Off。
（2）打开单元坐标系和线的方向：见图5(2)，Utility Menu>PlotCtrls>Symbols →ESYS：勾选On；LDIR：勾选ON；不显示边界条件符号，[/PBC]中选择None→OK。
图5 单元坐标系
单元坐标系的三个方向的坐标颜色与整体坐标系的颜色是相近的。经过观察发现，单元坐标系的X、Y和Z坐标的规定是：图5(3)和图5(4)中线的方向（关键点的连线顺序）为X方向，能与整体坐标系一致的尽量保持一致，比如单元坐标系的Z方向。单元坐标系同时满足右手系法则。
通过分析剪力图、弯矩图和单元坐标系的关系，可以总结出以下结论：
（1）内力也是采用截面法，选取单元坐标系离X轴较近的一段为研究对象，外力和内力（剪力和弯矩）保持平衡。 （2）剪力无论是正还是负，均画在+Y侧。如果剪力方向与单元坐标系的+Y方向一致，剪力为正；反之，为负。 （3）弯矩的正负：绕坐标轴旋转的方向一致，弯矩为正；反之，为负。
四、命令流
!模型1：关键点的连线顺序，从左到右
/PREP7
ET,1,BEAM188
KEYOPT,1,3,2
KEYOPT,1,4,2
MP,EX,1,2.1e11 !弹性模量
MP,PRXY,1,0.3 !泊松比
SECTYPE, 1, BEAM, CSOLID, , 0
SECOFFSET, CENT
SECDATA,0.01,0,0,0,0,0,0,0,0,0,0,0
K,1,0,0,0, ! AC梁的A、B和C
K,2,1,0,0,
K,3,2,0,0,
K,4,2,0,0, ! CD梁的C和D点
K,5,3,0,0,
LSTR,1,2 ! AC梁
LSTR,2,3
LSTR,4,5 ! CD梁
ESIZE,0,10, !单元份数
LMESH,all !网格划分
/VIEW,1,1,1,1
LPLOT
DK,1, , , ,0,UY,UZ,ROTX,ROTY
DK,5, , , ,0,ALL
FK,2,MZ,-20 ! B点力偶距
FK,3,FY,-20 !C点集中力
!分别耦合三个方向的平动自由度
CP,1,UX,12,22 !耦合UX
CP,2,UY,12,22 !耦合UY
CP,3,UZ,12,22 !耦合UZ
FINISH
/SOL
SOLVE
FINISH
/POST1
PLNSOL, U,Y, 0,1.0 !挠度
PLNSOL, ROT,Z, 0,1.0 !转角
ETABLE,SFY_I,SMISC,6 !剪力单元表
ETABLE,SFY_J,SMISC,19
PLLS,SFY_I,SFY_J,1,0 !剪力图
ETABLE,MZ_I,SMISC,3 !弯矩单元表
ETABLE,MZ_J,SMISC,16
PLLS,MZ_I,MZ_J,1,0 !弯矩图
!模型2：关键点的连线顺序，从右到左
/PREP7
ET,1,BEAM188
KEYOPT,1,3,2
KEYOPT,1,4,2
MP,EX,1,2.1e11 !弹性模量
MP,PRXY,1,0.3 !泊松比
SECTYPE, 1, BEAM, CSOLID, , 0
SECOFFSET, CENT
SECDATA,0.01,0,0,0,0,0,0,0,0,0,0,0
K,1,0,0,0, ! AC梁的A、B和C
K,2,1,0,0,
K,3,2,0,0,
K,4,2,0,0, ! CD梁的C和D点
K,5,3,0,0,
LSTR,2,1 ! AC梁
LSTR,3,2
LSTR,5,4 ! CD梁
ESIZE,0,10, !单元份数
LMESH,all !网格划分
/VIEW,1,1,1,1
LPLOT
DK,1, , , ,0,UY,UZ,ROTX,ROTY
DK,5, , , ,0,ALL
FK,2,MZ,-20 ! B点力偶距
FK,3,FY,-20 !C点集中力
!分别耦合三个方向的平动自由度
CP,1,UX,12,23 !耦合UX
CP,2,UY,12,23 !耦合UY
CP,3,UZ,12,23 !耦合UZ
FINISH
/SOL
SOLVE
FINISH
/POST1
PLNSOL, U,Y, 0,1.0 !挠度
PLNSOL, ROT,Z, 0,1.0 !转角
ETABLE,SFY_I,SMISC,6 !剪力单元表
ETABLE,SFY_J,SMISC,19
PLLS,SFY_I,SFY_J,1,0 !剪力图
ETABLE,MZ_I,SMISC,3 !弯矩单元表
ETABLE,MZ_J,SMISC,16
PLLS,MZ_I,MZ_J,1,0 !弯矩图
免责声明：本文系网络转载或改编，未找到原创作者，版权归原作者所有。如涉及版权，请联系删
155-2731-8020
