产品
前言：
间接耦合分析与直接耦合分析的一个很大的区别是单元选择问题。间接耦合分析时针对单一的物理场选取合适的单元即可，在另一个物理场情况下更改单元类型即可。而直接耦合分析选择单元时需要保证该单元具有所需的所有自由度。ANSYS帮助文档中可以查到很多专门用于直接耦合分析的耦合单元。
热结构间接耦合分析主要包括如下几个步骤：
第一步：进行温度场分析的前处理并写温度场物理分析文件
第二步：进行结构场分析的前处理并写结构场物理分析文件
第三步：读取温度场物理分析文件进行求解和后处理
第四步：读取结构场物理分析文件并读取温度场计算结果进行结构场求解和后处理
问题描述：
如下图二维界面图所示。A1为钢筒截面，内径0.1875，外径0.4，高0.05，热传导系数2.2。A2为铝筒截面，内径0.4，外径0.6，高0.05。钢筒内壁温度200，铝筒外壁70，热传导系数10.8。参考温度70。两截面的下边线Y方向为0位移约束，其余三边施加位移耦合。求取两筒的稳态应力分布情况。
热分析结果：
筒截面温度分布云图
结构分析结果：
扩展后的等效应力分布云图
命令流文件：
FINISH
/FILNAME,Exercise ! 定义分析文件名
! 第一步：进行温度场分析的前处理并写温度场物理分析文件
/prep7 ! 进入前处理器
et,1,plane77,,,1 ! 选择PLANE77热分析单元并设置为轴对称分析
mp,kxx,1,2.2 ! 定义钢筒热传导系数
mp,kxx,2,10.8 ! 定义铝筒热传导系数
rectng,.1875,.4,0,.05 ! 建立钢筒几何模型
rectng,.4,.6,0,.05 !建立铝筒几何模型
aglue, all ! 粘接各矩形
numcmp,area ! 压缩面编号
asel,s,,,1
aatt,1,1,1 ! 附于钢筒材料属性
asel,s,,,2
aatt,2,1,1 ! 附于铝筒材料属性
asel,all
esize,.05 ! 定义单元划分尺寸
mshkey,2 ! 设置为映射单元划分类型
amesh,all ! 划分单元
nsel,s,loc,x,.1875
d,all,temp,200 ! 施加钢筒内壁温度边界条件
nsel,s,loc,x,.6
d,all,temp,70 ! 施加铝筒外壁温度边界条件
nsel,all
physics,write,thermal ! 写温度场物理分析文件
! 第二步：进行结构场分析的前处理并写结构场物理分析文件
physics,clear ! 清空物理环境数据
ddel,all ! 删除温度场温度载荷
et,1,82,,,1 ! 选择结构分析单元
mp,ex,1,30e6 ! 定义钢筒结构场材料属性
mp,alpx,1,.65e-5
mp,nuxy,1,.3
mp,ex,2,10.6e6 ! 定义铝筒结构场材料属性
mp,alpx,2,1.35e-5
mp,nuxy,2,.33
nsel,s,loc,y,.05 ! 选择两厚壁筒顶面节点
cp,1,uy,all ! 耦合节点Y向自由度
nsel,s,loc,x,.1875 ! 选择钢筒内壁节点
nsel,a,loc,x,0.6
cp,2,ux,all ! 耦合节点X向自由度
nsel,s,loc,y,0 ! 选择两厚壁筒底面节点
d,all,uy,0 ! 施加Y向位移约束
nsel,all
tref,70 ! 定义参考温度
physics,write,struct ! 写结构场物理分析文件
save ! 存盘
finish
! 第三步：读取温度场物理分析文件进行求解和后处理
/solu
physics,read,thermal ! 读取温度场物理分析文件
solve ! 求解
finish
/post1 ! 进入通用后处理器
path,radial,2 ! 定义径向显示路径
ppath,1,,.1875
ppath,2,,.6
pdef,temp,temp ! 向所定义路径映射温度分析结果
pasave,radial,filea ! 保存路径文件
plpath,temp ! 显示沿路径温度变化曲线图
finish
! 第四步：读取结构场物理分析文件并读取温度场计算结果进行结构场求解和后处理
/solu
physics,read,struct ! 读取结构场物理分析文件
ldread,temp,,,,,,rth ! 读取温度场分析结果
solve ! 求解
finish
/post1 ! 进入通用后处理器
paresu,raidal,filea ! 读取已存路径文件
pmap,,mat ! 定义沿路径不连续区域处理方法
pdef,sx,s,x ! 向所定义路径映射X向应力分析结果
pdef,sz,s,z ! 向所定义路径映射Z向应力分析结果
plpath,sx,sz ! 显示沿路径X和Z向应力分析曲线
plpagm,sx,,node ! 在几何模型上显示X向应力分布云图
plnsol,s,eqv,0,1 ! 显示等效应力分析结果
/expand,27,axis,,,10 ! 设置轴对称分析结果扩展选项
plnsol,s,eqv,0,1 !显示两厚壁筒三维扩展的等效应力分析结果
finish
免责声明：本文系网络转载或改编，未找到原创作者，版权归原作者所有。如涉及版权，请联系删
155-2731-8020
