ANSYS壳单元在箱梁结构分析中的应用案例详解

! Analysis a box beam section with shell elements of ANSYS
! 用ansys的壳体单元分析箱梁
! Box dimension: 10*4*4m with shell thickness of 0.04m
! By Lu Xinzheng, Depart. Civil Engineering, Tsinghua University, Beijing
! 陆新征，清华大学土木系
! Aug. 2004
! Define the Element
! 定义单元
/PREP7
!*
ET,1,SHELL93
!*
! Define the section for shells
! 定义壳单元截面
R,1,.04, , , , , ,
!*
! Define the material
! 定义材料
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,EX,1,,200e9
MPDATA,PRXY,1,,.3
! Setup the model
! 建模
! Define the keypoints
! 定义关键点
k,1,0,0,0
k,2,4,0,0
k,3,4,4,0
k,4,0,4,0
! Define the lines
! 定义线
l,1,2
l,2,3
l,3,4
l,4,1
! Define the section area
! 定义截面
a,1,2,3,4
! Extrude a volumn from area
! 从面拉伸得到体
VEXT,1, , ,0,0,10,,,,
! Delete useless volumn and areas
! 删除不必要的体和面
VDELE, 1
ADELE,1,2,1
! Mesh
! 划分网格
ESIZE,0.5,0,
AMESH,ALL
!*
FINISH
/SOL
! Fixed end
! 固定端部
DL,1, ,ALL,
DL,2, ,ALL,
DL,3, ,ALL,
DL,4, ,ALL,
! Give the pressure on the top surface
! 顶部施加压力
SFA,5,2,PRES,1

SOLVE
FINISH

/POST1
! Display the deformation
! 绘制变形
PLDISP,0
! Select the mid-section of the shells
! 选定壳中部截面
shell,mid
! Define a path to plot the stress
! 定义一个路径来绘制应力
PATH,MidPath1,4,30,20,
! Define path with nodes
! 用节点来定义路径
PPATH,1,89
PPATH,2,34
PPATH,3,570
PPATH,4,1066
PATH,STAT
!*
AVPRIN,0,0,
!*
! Map stress Z to the path
! 将Stress Z映射到路径
PDEF, ,S,Z,AVG
/PBC,PATH, ,0
! Plot the stress
! 绘制应力
PLPATH,SZ
FINISH