许可优化
许可优化
产品
产品
解决方案
解决方案
服务支持
服务支持
关于
关于
软件库
当前位置:服务支持 >  软件文章 >  Standard Surface Shader练习记录,标准材质学习

Standard Surface Shader练习记录,标准材质学习

阅读数 8
点赞 0
article_banner

1:漫反射模型

1.1 效果

根据光照方向不同亮度表现

代码块

Shader "Custom/4-Diffuse"
{
    Properties
    {
        _Color ("Color", Color) = (1,1,1,1)
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 200

        CGPROGRAM
        #pragma surface surf Standard fullforwardshadows
        #pragma target 3.0

        struct Input
        {
            float2 uv_MainTex;
        };

        fixed4 _Color;

        UNITY_INSTANCING_BUFFER_START(Props)
            // put more per-instance properties here
        UNITY_INSTANCING_BUFFER_END(Props)

        void surf (Input IN, inout SurfaceOutputStandard o)
        {
            fixed4 c =  _Color;
            o.Albedo = c.rgb;
        }
        ENDCG
    }
    FallBack "Diffuse"
}

使用标准光照模型,只进行了颜色采样。

2:UV移动

2.1 效果


     动图
   

记得调节图片的WrapMode为Repeat

代码块

Shader "Custom/5-TextureMove"
{
    Properties
    {
        _Color ("Color", Color) = (1,1,1,1)
        _MainTex ("Albedo (RGB)", 2D) = "white" {}
        _ScrollX("ScrollX",Range(0,10))=2
        _ScrollY("ScrollY",Range(0,10))=2
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 200

        CGPROGRAM
        #pragma surface surf Standard fullforwardshadows

        #pragma target 3.0

        sampler2D _MainTex;

        struct Input
        {
            float2 uv_MainTex;
        };

        fixed4 _Color;
        float _ScrollX;
        float _ScrollY;

        UNITY_INSTANCING_BUFFER_START(Props)
        UNITY_INSTANCING_BUFFER_END(Props)

        void surf (Input IN, inout SurfaceOutputStandard o)
        {
            //进行了xz方向的移动
            float ScrollXValue=_ScrollX*_Time.y;
            float ScrollYValue=_ScrollY*_Time.y;
            float2 currUV=IN.uv_MainTex+float2(ScrollXValue,ScrollYValue);
            //纹理采样
            fixed4 col=tex2D(_MainTex,currUV);

            o.Albedo=col.rgb*_Color;
            o.Alpha=col.a;
        }
        ENDCG
    }
    FallBack "Diffuse"
}

2.2 关于_Time

:(t 为游戏运行时间,单位为秒),变化较慢,适合控制缓慢变化的效果                          (如云朵飘动)。

:(原始时间),常用于控制中等速度的动画(如波浪起伏)。

:,变化速度是原始时间的 2 倍,适合快速变化的效果(如闪烁、脉冲)。

:,变化更快,用于极快的动画(如高频闪烁)。

3:透明效果

3.1:效果


透过前面的窗花看见后面的正方体

代码块

Shader "Custom/7-Transparent"
{
    Properties
    {
        _Color ("Color", Color) = (1,1,1,1)
        _MainTex ("Albedo (RGB)", 2D) = "white" {}
    }
    SubShader
    {
        Tags { "RenderType"="Transparent" "Queue"="Transparent" "IgnoreProjector"="True"}
        LOD 200

        CGPROGRAM
        #pragma surface surf Standard alpha:fade

        #pragma target 3.0

        sampler2D _MainTex;

        struct Input
        {
            float2 uv_MainTex;
        };

        fixed4 _Color;

        UNITY_INSTANCING_BUFFER_START(Props)
        UNITY_INSTANCING_BUFFER_END(Props)

        void surf (Input IN, inout SurfaceOutputStandard o)
        {
            //纹理采样
            fixed4 c = tex2D (_MainTex, IN.uv_MainTex) * _Color;
            o.Albedo = c.rgb;
            o.Alpha = c.a;
        }
        ENDCG
    }
    FallBack "Diffuse"
}

将渲染类型和队列都改为透明效果,忽略投影器效果可以提高性能,alpha:fade表示启用透明度混合,支持半透明效果。

4:全息投影效果

4.1:效果


原图


全息效果

代码块

Shader "Custom/8-Hology"
{
    Properties
    {
        _Color ("Color", Color) = (1,1,1,1)
        _MainTex ("Albedo (RGB)", 2D) = "white" {}
        _edgeEffect("EdgeEffect",Range(0,1))=0
    }
    SubShader
    {
        Tags { "RenderType"="Transparent" "Queue"="Transparent" "IgnoreProjector"="True"}
        LOD 200
        Cull Off
        Lighting Off

        CGPROGRAM
        #pragma surface surf Lambert alpha:fade
        #pragma target 3.0
        sampler2D _MainTex;

        struct Input
        {
            float2 uv_MainTex;
            float3 worldNormal;
            float3 viewDir; 
        };

        fixed4 _Color;
        float _edgeEffect;

        UNITY_INSTANCING_BUFFER_START(Props)
        UNITY_INSTANCING_BUFFER_END(Props)

        void surf (Input IN, inout SurfaceOutput o)
        {
            //纹理采样
            fixed4 col=tex2D(_MainTex,IN.uv_MainTex)*_Color;

            //使用点乘计算边缘,视线与法线垂直为0,表示边缘
            float edge=1-(abs(dot(IN.viewDir,IN.worldNormal)));
            //进行参数调整
            edge=edge*(1-_edgeEffect)+_edgeEffect;

            o.Albedo=col.rgb;
            o.Alpha=col.a*edge;
        }
        ENDCG
    }
    FallBack "Diffuse"
}

     

1:Cull Off:关闭剔除模式,可以完整显示整个模型,此外还有:Cull Back(剔除背面),                           Cull Front(剔除前面)

2:Lighting Off:关闭光照影响。

3:使用点乘,当视线(三角片到视角的连线)和法线(垂直三角片的直线)垂直时为0,取值是 (-1,1)。也就是视线和法线越趋向平行,透明度越低,也就是非边缘。

4:edge=edge*(1-_edgeEffect)+_edgeEffect:类似a*(1-b)+b的差值效果,混合a和b的取值。

5:纹理混合

5.1:效果


混合效果


参数

代码块

Shader "Custom/9"
{
    Properties
    {
        _Color ("Color", Color) = (1,1,1,1)
        _ColorA("ColorA",Color)=(1,1,1,1)
        _ColorB("ColorB",Color)=(1,1,1,1)
        _RTex("RTex",2D)=""{}
        _GTex("GTex",2D)=""{}
        _BTex("BTex",2D)=""{}
        _ATex("ATex",2D)=""{}
        _BlendTex("BlendTex",2D)=""{}
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 200

        CGPROGRAM
        #pragma surface surf Lambert
        #pragma target 3.0

        sampler2D _RTex;
        sampler2D _GTex;
        sampler2D _BTex;
        sampler2D _ATex;
        sampler2D _BlendTex;
        float4 _Color; 
        float4 _ColorA;
        float4 _ColorB;

        struct Input
        {
            float2 uv_BlendTex;
        };

        UNITY_INSTANCING_BUFFER_START(Props)
        UNITY_INSTANCING_BUFFER_END(Props)

        void surf (Input IN, inout SurfaceOutput o)
        {
            //纹理取样,都使用同一个混合纹理样本
            fixed4 blendData=tex2D(_BlendTex,IN.uv_BlendTex);
            fixed4 RData=tex2D(_RTex,IN.uv_BlendTex);
            fixed4 GData=tex2D(_GTex,IN.uv_BlendTex);
            fixed4 BData=tex2D(_BTex,IN.uv_BlendTex);      
            fixed4 AData=tex2D(_ATex,IN.uv_BlendTex);
            //纹理混合
            float4 finalData;
            finalData=lerp(RData,GData,blendData.r);
            finalData=lerp(finalData,BData,blendData.g);
            finalData=lerp(finalData,AData,blendData.b);
            finalData.a=1.0f;
            //颜色插值
            float4 finalColor=lerp(_ColorA,_ColorB,_Color.r);
            //输出赋值
            o.Albedo=finalData*_Color.rgb;
            o.Alpha=finalData.a;
        }
        ENDCG
    }
    FallBack "Diffuse"
}

     

首先进行纹理采样,都使用同一个纹理图,如果每一个都有一张纹理图,会超出报错,将其他纹理图使用lerp插值到混合纹理图里面的rgb里面,最后进行颜色差值调控即可。

6:圆形显示效果

6.1:效果


代码块

ader "Custom/10-Circle"
{
    Properties
    {
        _MainTex("MainTex",2D)=""{}
        _MainColor("MainColor",Color)=(1,0,0,1)
        _Radius("Radius",float)=10
        _Width("Width",float)=2
        _Center("Center",Vector)=(0,0,0,0)
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 200

        CGPROGRAM
        #pragma surface surf Standard fullforwardshadows

        #pragma target 3.0

        struct Input
        {
            float2 uv_MainTex;
            float3 worldPos;
        };

        sampler2D _MainTex;
        fixed4 _MainColor;
        float _Radius;
        float _Width;
        float4 _Center;

        UNITY_INSTANCING_BUFFER_START(Props)
        UNITY_INSTANCING_BUFFER_END(Props)

        void surf (Input IN, inout SurfaceOutputStandard o)
        {
            //判断半径,大于半径且小于宽度进行颜色绘制,否则就是纹理颜色
            if(distance(IN.worldPos,_Center)>_Radius&&distance(IN.worldPos,_Center)<(_Radius+_Width))
            {
                //绘制红色
                o.Albedo=_MainColor.rgb;
            }
            else
            {
                //纹理颜色
                o.Albedo=tex2D(_MainTex,IN.uv_MainTex).rgb;
            }
        }
        ENDCG
    }
    FallBack "Diffuse"
}

在半径宽度内的输出目标颜色,否则输出纹理颜色,在Terrain里面赋值此材质。



免责声明:本文系网络转载或改编,未找到原创作者,版权归原作者所有。如涉及版权,请联系删

相关文章
技术文档
QR Code
微信扫一扫,欢迎咨询~
customer

online

联系我们
武汉格发信息技术有限公司
湖北省武汉市经开区科技园西路6号103孵化器
电话:155-2731-8020 座机:027-59821821
邮件:tanzw@gofarlic.com
Copyright © 2023 Gofarsoft Co.,Ltd. 保留所有权利
遇到许可问题?该如何解决!?
评估许可证实际采购量? 
不清楚软件许可证使用数据? 
收到软件厂商律师函!?  
想要少购买点许可证,节省费用? 
收到软件厂商侵权通告!?  
有正版license,但许可证不够用,需要新购? 
联系方式 board-phone 155-2731-8020
close1
预留信息,一起解决您的问题
* 姓名:
* 手机:

* 公司名称:

姓名不为空

姓名不为空

姓名不为空
手机不正确

手机不正确

手机不正确
公司不为空

公司不为空

公司不为空