单层平壁热传导分析详解

一、问题描述

厚度b = 500 mm的平壁，宽度W和高度H均为3 m。其左侧表面温度t₁= 900 ℃，右侧表面温度t₂= 250 ℃。假设平壁材料的导热系数不随温度改变，导热系数λ = 1.575 W/(m²·℃)。计算平壁内的温度分布、导热热通量和温度梯度。

二、问题分析

实际物体均是具有空间的三维结构，由于本例只沿着壁厚这一个方向进行热传导，因此可通过三种方式建立模型：

单层平壁的热传导分析的图1

1）一维模型：由于本例热传导只沿着壁厚方向，可简化成一维的传热问题。采用热分析LINK33杆单元，平壁面积由实常数输入。实常数中输入面积（宽度W 乘以高度H）9 m²，平壁的壁厚b则是热分析LINK33单元的长度。见图1(1)。

2）二维模型：采用热分析PLANE77平面单元，在单元选项中选择带有厚度的平面，见图2.1.1(2)。平面的厚度即为平壁的壁厚b，平面的高度H输入3 m；见图1(2)。

3）三维模型：采用热单元SOLID70三维单元，沿着传热方向即为平壁的壁厚b，宽度W和高度H输入3 m。见图1(3)。

材料属性中输入导热系数（导热率）。在后处理中，输出温度、热通量和温度梯度的云图，提取导热速率的数值。

三、热通量、温度梯度和导热速率与解析解对比

单层平壁的热传导分析的图2

图2给出了三维模型的热分析结果云图，表1给出了热传导分析计算结果对比。本算例为单层平壁导热问题，热量只沿壁厚方向传递，沿着垂直壁厚的其他两个方向认为无热量传递，因此采用一维、二维和三维模型的计算结果相同。

单层平壁的热传导分析的图3

单层平壁的热传导分析的图4

1) 温度云图

单层平壁的热传导分析的图5

2) 温度梯度和热通量云图

图2 热分析结果云图

四、计算步骤

1．进入ANSYS

程序→ANSYS → ANSYS Product Launcher→ 改变working directory到指定文件夹→job name：输入file。

2．设置计算类型

Main Menu> Preferences→ 选择Thermal→ OK。

3．定义单元属性

1）单元类型，见图3。Main Menu> Preprocessor> Element Type> Add/ Edit/ Delete→ Add→ 选择SOLID70单元，即在左列表框中选择Thermal Solid，在右列表框中选择Brick 8node 70→ OK。

单层平壁的热传导分析的图6

图3 热分析单元

2）热传导系数，见图4。Main Menu> Preprocessor> Material Props> Material Models→ Thermal→Conductivity → Isotropic → KXX输入1.575→ OK。

单层平壁的热传导分析的图7

图4 导热系数

4．建立几何模型

1）建立几何体，见图5。Main Menu> Preprocessor> Modeling> Create> Volumes> Block> By Dimensions→ X1, X2输入0和0.5，Y1, Y2输入0和3，Z1, Z2输入0和3。

单层平壁的热传导分析的图8

图5 三维几何体

2）ISO视图显示：屏幕右上角单击IsometricView → 屏幕中单击右键。

5．划分单元

1）设置单元属性：Main Menu> Preprocessor> Meshing> Mesh Tool→在Element Attributes下方选择Volumes，点按Set→Pick All→ OK→ 选择MAT: 1，TYPE: 1 → OK。

2）设置单元尺寸：Main Menu> Preprocessor> Meshing> Mesh Tool→ 在Size Controls下方选择GlobalSet→ SIZE中输入0.25→ OK。

3）划分网格：Main Menu> Preprocessor> Meshing> Mesh Tool→ 选择Volumes, Hex, Mapped→ Mesh→ Pick All→ OK。

4）保存网格模型：Utility Menu> File> Save as→ 输入Thermal_mesh.db。

6．施加边界条件

1）打开面编号：Utility Menu> PlotCtrls> Numbering→ /PNUM中选择AREA→ OK。

2）显示面：Utility Menu> Plot>Areas。

3）施加壁面温度边界

①左侧表面温度t₁=900℃，见图6。Main Menu> Solution>Define Loads> Apply> Thermal> Temperature> On Areas →拾取面A5 → OK → Lab2中选择TEMP；VALUE输入900 → OK。

单层平壁的热传导分析的图9

图6 施加温度边界

②右侧表面温度t₂=250℃：Main Menu> Solution> DefineLoads> Apply> Thermal> Temperature> On Areas →拾取面A6 → OK → Lab2中选择TEMP；VALUE输入250→ OK。

7．求解

1）求解前保存模型：Utility Menu> File> Save as→ 输入Thermal_load.db。

2）求解前选择所有：Utility Menu> Select> Everything

3）开始求解计算：Main Menu> Solution> Slove> Current LS→ File> Close→ OK→ [Sloution is done]: Close，完成求解计算。

4）求解后保存模型：UtilityMenu> File> Save as→ 输入Thermal_solve.db。

8．通用后处理

单层平壁的热传导分析的图10

图7 云图结果

1）温度分布云图：见7(1)。MainMenu> General Postproc> Plot Results> Contour Plot> Nodal Solu→Nodal Solution→ DOF Solution→ Nodal Temperature→ OK。单位：℃。

2）温度梯度云图：见7(2)。MainMenu> General Postproc> Plot Results> Contour Plot> Nodal Solu→Nodal Solution→ DOF Solution→ Thermal Gradient→ OK。单位：℃/m。

3）热通量云图：见7(3)。Main Menu> General Postproc>Plot Results> Contour Plot> Nodal Solu→ Nodal Solution→ DOF Solution→Thermal Flux→ OK。单位：W/m²。

单层平壁的热传导分析的图11

图8 热流量

4）计算热流量

①选择面A5：见8(1)。Utility Menu> Select> Entities →从上到下依次选择：Areas，By Num/Pick，From Full，OK →拾取面A5。

②显示面：Utility Menu> Plot>Areas。

③节点依附到面上：见8(2)。Utility Menu> Select> Entities →从上到下依次选择：Nodes，Attached to，Areas all，From Full，Apply，Replot。

④显示节点：Utility Menu> Plot> Nodes。

⑤计算热流量：见8(3)。Main Menu> General Postproc> Nodal Calcs>Total Force Sum。计算得出的热流量为-18427.50 W，见8(4)。热流量负值表示流入，正值表示流出。

五、命令流

!《化工原理》，第三版，杨祖荣，第124页

b1=500e-3 !平壁厚度

lambda1=1.575 !导热系数（热导率），W/(m.℃)

t1=900 !左侧表面温度

t2=250 !右侧表面温度

W1=3 !平壁宽度

H1=3 !平壁高度

A1=W1*H1

dt=t1-t2

R1=b1/(lambda1*A1) !导热热阻

Q1=dt/R1 !导热速率W

TF=Q1/A1 !热通量（W/m^2）Thermal Flux

TG=TF/lambda1 !温度梯度（m/℃）Thermal Gradient

!-----------------------------一维模型------------------------

/PREP7

ET,1,LINK33 !热单元

R,1,9, !传热面积

MP,KXX,1,1.575 !导热系数（热导率）

K,1,0,0,0, !关键点

K,2,0.5,0,0,

LSTR,1,2 !几何线

ESIZE,0.25,0, !单元尺寸

LMESH,1

/VIEW,1,1,1,1

DK,1,,900,,0,TEMP !左侧温度

DK,2,,250,,0,TEMP !右侧温度

FINISH

/SOL

SOLVE

FINISH

/POST1

/ESHAPE,1

PLNSOL,TEMP,,0 !温度分布℃

PLNSOL,TG,X,0 !温度梯度℃/m

PLNSOL,TF,X,0 !热通量W/m2

!-----------------------------二维模型------------------------

/PREP7

ET,1,PLANE77 !热单元

MP,KXX,1,1.575 !导热系数（热导率）

RECTNG,0,0.5,0,3, !几何面

ESIZE,0.25,0, !单元尺寸

MSHAPE,0,2D

MSHKEY,1

AMESH,all

DL,4,,TEMP,900,0 !左侧温度

DL,2,,TEMP,250,0 !右侧温度

FINISH

/SOL

ALLSEL,ALL

SOLVE

FINISH

/POST1

PLNSOL, TEMP,, 0 !温度云图℃

PLNSOL, TG,X, 0 !温度梯度℃/m

PLNSOL, TF,X, 0 !热通量W/m2

LSEL,S,,,4 !选择线L4

LPLOT !显示线

NSLL,S,1 !节点依附到线

NPLOT !显示节点

FSUM,0,ALL !计算热流量

!-----------------------------三维模型------------------------

/PREP7

ET,1,SOLID70 !热单元

MP,KXX,1,1.575 !导热系数（热导率）

BLOCK,0,0.5,0,3,0,3, !三维几何体

ESIZE,0.25,0, !单元尺寸

MSHAPE,0,3D

MSHKEY,1

VMESH,1

DA,5,TEMP,900 !左侧温度

DA,6,TEMP,250 !右侧温度

FINISH

/SOL

ALLSEL,ALL

SOLVE

FINISH

/POST1

PLNSOL, TEMP,, 0 !温度云图℃

PLNSOL, TG,X, 0 !温度梯度℃/m

PLNSOL, TF,X, 0 !热通量W/m2

ASEL,S,,,5 !选择面A5

APLOT !显示面

NSLA,S,1 !节点依附到面

NPLOT !显示节点

FSUM,0,ALL !计算热流量

免责声明：本文系网络转载或改编，未找到原创作者，版权归原作者所有。如涉及版权，请联系删

返回上级列表

下一篇: FLUENT/Mechanical流固双向耦合模拟技术 >