产品
近日，有不少同学向水哥咨询螺旋箍筋的相关问题，今天终于忙里偷闲，得一闲暇下午，趁空与大家分享下ANSYS中螺旋箍筋的建模方法。
螺旋箍筋可以分为矩形螺旋箍筋以及圆环螺旋箍筋，两者建模思路一样，相对来讲，圆环螺旋箍筋建模会稍微比较繁琐一点，这里水哥就以圆环螺旋箍筋建模为例，说说其建模方法。
本文案例如下：
某圆柱，直径1000，长度2550，采用C40混凝土，HRB400钢筋，配置螺旋箍筋，间距为150，保护层厚度为50，试采用ANSYS建立该柱有限元模型。结构几何模型如下：
建模思路以及注意的几个关键点：
一、总体建模思路与常见的通过划分几何线形成钢筋单元不同，螺旋钢筋建模通过节点建立单元的方式形成钢筋单元。
二、建模坐标系为柱坐标系。
三、确定每一半圈钢筋的划分段数，并根据划分段数确定整体模型的竖向划分段数。
四、定义数组，通过位置坐标获取在特定位置处的节点编号，存入数组。
五、建立相应的钢筋单元。
螺旋箍筋的建模需要一定的编程基础，限于篇幅，本次仅仅罗列出关键地方的命令流，并进行一定的讲解。
！========
finish
/clear
/prep7
et,1,solid65
et,2,link8
!==========
材料、实常数定义
!===========
!建立外圈混凝土，并切分出纵筋线
cyl4,,,450,,500,360,2550
wprota,,,90
*do,i,1,10
wprota,,18
vsbw,all
*enddo
wpcsys,-1
!==============
!按照150距离内切分为10份的方法切割出轮廓
!保证后续划分网格时在我们需要的位置有结点
wpoffs,,,150
vsbw,all
wpoffs,,,150
vsbw,all
*do,i,1,13
*do,j,1,10
wpoffs,,,15
vsbw,all
*enddo
vsel,u,loc,z,0,150*i+300
*enddo
wpoffs,,,150
vsbw,all
wpcsys,-1
allsel,all
!============
!建立内部混凝土柱，并进行布尔运算
cyl4,,,,,450,360,2550
vglue,all
!============
!=============
!选择端部箍筋线，划分网格
csys,1
lsel,s,loc,z,150
lsel,a,loc,z,2400
lsel,r,loc,x,450
latt,2,2,2
lesize,all,15
lmesh,all
!===================
!选择纵筋线，划分网格
csys,1
lsel,s,loc,y,0
*do,i,1,19
lsel,a,loc,y,18*i
*enddo
lsel,r,loc,x,450
latt,2,3,2
lesize,all,15
lmesh,all
!==================
!进行体划分
vatt,1,1,1
esize,15
vsweep,all
!==================
!本文之精华所在
!获取各个特定位置处的箍筋结点编号，并存入数组
csys,1
*dim,nodeA,array,,121
kk=0
*do,j,1,6
*do,i,1,20
xx=450
YY=18*(i-1)
zz=300+15*(i-1)+300*(j-1)
kk=kk+1
nodenum=node(xx,yy,zz)
nodeA(1,kk)=nodenum
*enddo
*enddo
*do,i,1,11
xx=450
YY=18*(i-1)
zz=300+15*(i-1)+300*6
kk=kk+1
nodenum=node(xx,yy,zz)
nodeA(1,kk)=nodenum
*enddo
!============
type,2
mat,2
real,2
*do,i,1,130
e,nodeA(1,i),nodeA(1,i+1)
*enddo
螺旋箍筋效果如下：
矩形螺旋箍筋建模和本文思路如出一辙，这里就不在演示了
免责声明：本文系网络转载或改编，未找到原创作者，版权归原作者所有。如涉及版权，请联系删
155-2731-8020
